пятница, 15 апреля 2016 г.

Halt next object call

ObjectVirus allows very simple implementation of object centric debugging. We can infect given object by virus which will halt any message send.
Let's create new GhostBehaviour for this:

GHGhostBehaviour subclass: #GHObjectCallHalt
      instanceVariableNames: ''
      classVariableNames: ''
      package: 'Ghost-ObjectCallHalt'

GHGhostBehaviour>>send: aMessage to: anObject
       | method breakpoint |
       anObject recoverFromVirus.
       self halt.
       ^aMessage sendTo: anObject

First we disable interception behaviour to not halt any following messages (to get halt once logic). And then we halt message processing. It will open debugger on any message send. And to access target method "step into" button should be pressed few times in the debugger.
To activate such behaviour on objects we can create suitable method:

Object>>haltOnNextCall
       | virus |
       virus := GHObjectVirus behaviour: GHObjectCallHalt new.
       virus infect: self

And now we can play with this:

      point := 2@3.
      point haltOnNextCall.
      0@0 distanceTo: point

It will open debugger:


Of course we don't want to step into target method manually. We want to see target method just in the debugger. To achieve this we can set up breakpoint on target method and run it instead of halt message processing:

GHGhostBehaviour >>send: aMessage to: anObject
       | method breakpoint |
       anObject recoverFromVirus.
       method := anObject class lookupSelector: aMessage selector.

       breakpoint := Breakpoint new
             node: method ast;
             once.
       breakpoint link condition: [ :receiver | receiver == anObject ] arguments: #(#object).
       breakpoint install.

       ^aMessage sendTo: anObject

And with this change we will see what we want:


Debugger shows Point>>x method because #distanceTo: asks #x and #y of given point to compute distance:


Last thing which is not nice is that we see all message interception logic on the debugger stack view. Fortunately Pharo stack model allows context manipulation and we can really remove unneeded stack elements from execution context:

GHGhostBehaviour >>send: aMessage to: anObject
       | method breakpoint |
       anObject recoverFromVirus.
       method := anObject class lookupSelector: aMessage selector.

       breakpoint := Breakpoint new
             node: method ast;
             once.
       breakpoint link condition: [ :receiver | receiver == anObject ] arguments: #(#object).
       breakpoint install.

       self activateTargetMethodOf: aMessage for: anObject

GHGhostBehaviour >>activateTargetMethodOf: aMessage for: anObject
       | targetContext sender objectClass |
       sender := thisContext.
       [ sender selector == #cannotInterpret: ] whileFalse: [ sender := sender sender ].
       thisContext terminateTo: sender sender.
       "We should not use direct message to object because we propaply already install breakpoint to it"
       objectClass := GHMetaMessages extractClassOf: anObject.
       targetContext := thisContext sender
             activateMethod: (objectClass lookupSelector: aMessage selector)
             withArgs: aMessage arguments
             receiver: anObject
             class: objectClass.

       targetContext jump

It covers our tracks of "halt-virus" infection:


At the end we can extend Pharo debugger with new button "Run to next self send" which will resume process execution and halt on next call to current receiver:

ResumeDebugAction subclass: #GHRunToNextSelfCallDebugAction
       instanceVariableNames: ''
       classVariableNames: ''
       package: 'Ghost-ObjectCallHalt'

GHRunToNextSelfCallDebugAction >>defaultLabel

       ^ 'Run to next self call'

GHRunToNextSelfCallDebugAction >>id

       ^ #runToNextObjectCall

GHRunToNextSelfCallDebugAction class >>gtStackDebuggingActionFor: aDebugger
       <gtStackDebuggingAction>

       ^ (self forDebugger: aDebugger)
             icon: GLMUIThemeExtraIcons glamorousPlay

GHRunToNextSelfCallDebugAction >>executeAction

       self currentContext receiver haltOnNextCall.

       ^super executeAction.

And with these debugger will be looked like:


And if you press new button debugger will be opened on #y method of current point:


Code is hosted in Ghost repository. You can use it in your development process:

Metacello new
  baseline: 'Ghost';
  repository: 'github://dionisiydk/Ghost';
  load: 'ObjectCallHalt'

среда, 6 апреля 2016 г.

New version of Mocketry 3.0

New version of Mocketry is out. You can load it from https://github.com/dionisiydk/Mocketry by 
Metacello new
  baseline: 'Mocketry';
  repository: 'github://dionisiydk/Mocketry';
  load
In this version I try to provide most simple way to stub any message to any object and to verify any occurred behaviour. 
It was presented at PharoDays2016 conference:
Here I show full details about Mocketry

Create mocks easily

To create mock just use #new
yourMock := Mock new.
Mocketry not requires any special context variables for this.
Also Mocketry implements auto naming logic to retrive variable names from test context. Inside test yourMock will be shown as "a Mock(yourMock)" (in debugger).
But if you need special name you can specify it:
Mock named: 'yourMock'
You can look at it livelly in MockTests.
Also there is way to get multiple mocks at once:
[ :mockA :mockB | "your code here" ] runWithMocks

Stub any message sends

To stub message send just send message #stub to object and following message will create expectation:
mock := Mock new.

mock stub someMessage willReturn: 100.

mock someMessage should be: 100.
You can stub any objects. It is not only about mocks:
rect := 0@0 corner: 2@3.

rect stub width willReturn: 1000.

rect area should be: 3000 "are = width * height"
And you can do this with globals too:
DateAndTime stub now willReturn: #constantValue.

DateAndTime now should be: #constantValue.
But you should be carefull with globals. Don't try
Array stub new.
It will crash image. And if you stub global from workspace it is your responsibility to recover it from stub behaviour. Do it by this:
DateAndTime recoverFromGHMutation.
In case when you stub global inside test Mocketry automatically recovers all global stubs when test completes.
Also with Mocketry you can define expectations for set of objects. For example you can stub message to ANY object:
Any stub width willReturn: 100.

mock := Mock new.
mock width should be: 100.

rect := 0@0 corner: 2@3.
rect stub. "#stub activates message intercection for real object. Without it following sentence will not work"

rect area should be: 300.
Or you can stub ANY message to particular object:
mock := Mock new.

mock stub anyMessage willreturn:: 100.

mock someMessage should be: 100.
mock someMessage2 should be: 100.
And both variants are supported:
Any stub anyMessage willReturn: 100.

mock := Mock new.
mock someMessage should be: 100.

rect := 0@0 corner: 2@3.
rect stub.

rect area should be: 100.
rect width should be: 100.
Any class is specific object spec which means "any" object. You can uses any kind of specs:
(Kind of: Rectangle) stub width willReturn: 100.

rect := 0@0 corner: 2@3.
rect stub.

rect area should be: 300.

rect2 := 0@0 corner: 4@5.
rect2 stub.

rect2 area should be: 500

Stub message sends with arguments

In place of message arguments you can use expected objects itself. Or you can put specifications for expected arguments:
mock stub messageWith: arg1 and: arg2
mock stub messageWith: Any and: arg2
mock stub messageWith: [:arg | true]
mock stub messageWith: (Kind of: String) and: arg2
mock stub messageWith: (Instance of: Float) & (Satisfying for: [:arg | arg > 10]).
Last defined expectation has more priority than previous one. It allows you to define default expectations in setUp method and override it in particular tests. Following example shows it:
mock := Mock new.
(mock stub messageWith: (Instance of: SmallInteger)) willReturn: #anyInt.
(mock stub messageWith: (Kind of: String)) willReturn: #anyString.
(mock stub messageWith: 10) willReturn: #ten.

(mock messageWith: 10) should be: #ten.
(mock messageWith: 20) should be: #anyInt.
(mock messageWith: 'test' should be: #anyString

Expected actions for stubs

There are different kind of expected actions:
mock := Mock new.

mock stub someMessage willReturn: #result.
mock someMessage should be: #result.

mock stub someMessage willRaise: ZeroDivide new.
[mock someMessage] should raise: ZeroDivide.

(mock stub someMessageWith: #arg) will: [#result].
(mock someMessageWith: #arg) should be: #result.

(mock stub someMessageWith: #arg1 and: #arg2) will: [:arg1 :arg2 | arg1, arg2].
(mock someMessageWith: #arg1 and: #arg2) should equal: 'arg1arg2'.

mock stub someMessage willReturnValueFrom: #(result1 result2).
mock someMessage should be: #result1.
mock someMessage should be: #result2

Extra conditions on message sends

It is possible to verify arbitrary condition when expected message is going to be executed. For example:
mock := Mock new.
mock someMessage
    when: [flag] is: (Kind of: Boolean);
    when: [flag] is: true;
    when: [ flag ] satisfy: [ :object | true or: [ false ] ].

flag := true.
mock someMessage. "not failes"

flag := false.
mock someMessage "will fail immediately on call by last condition: flag should be true"

flag := #flag.
mock someMessage "will fail immediately on call by first condition: flag should be boolean"
Also Mocketry implements process related condition to check that message was synchronously sent (relative to test process):
mock stub someMessage shouldBeSentInThisProcess.
[ mock someMessage ] fork. "will fail immediately on call".

mock stub someMessage shouldBeSentInAnotherProcess.
[ mock someMessage ] fork. "will not fail".
mock someMessage. "will fail immediately on call"

Message sends usage rules

It is possible to specify how much times expectation can be used:
mock := Mock new.

mock stub someMesage willReturn: #default.
mock stub someMessage willReturn: 300; use: 3.
mock stub someMessage willReturn: 200; useTwice.
mock stub someMesage willReturn: 100 useOnce.

"last defined expectation is more preferred then previously defined"
mock someMessage should be: 100.

mock someMessage should be: 200.
mock someMessage should be: 200.

mock someMessage should be: 300.
mock someMessage should be: 300.
mock someMessage should be: 300.

mock someMessage should be: #default

Unexpected messages. Automocks

Mock returns another special mock for unexpected messages (when no expectation is defined for received message):
mock := Mock new.

automock := mock someMessage.

automock should beInstanceOf: MockForMessageReturn.
And any message to this mock will produce another automock. It means that your tests will not fail if you will not define any expectation for your mocks. It allows you put only required detailes inside your tests which really make sense for tested aspect of functionality. Anything else does not matters.
Also to improve this idea automock try to play role of false in boolean expressions.
mock := Mock new.
returnedMock := mock someMessage.

result := returnedMock ifFalse: [ #falseBranch ] ifTrue: [ #trueBranch ].

result should be: #falseBranch.
returnedMock should be: false
And play zero in arithmetic
mock := Mock new.
returnedMock := mock someMessage.

result := 1 + returnedMock.
result should equal: 1.
returnedMock should equal: 0

Stub group of message sends

There is way to stub multiple message sends at once:
mock := Mock new.
rect := 0@0 corner: 2@3.
rect stub.

[ mock someMessage willReturn: 10.
rect width willReturn: 1000 ] should expect.

mock someMessage should be: 10.
rect area should be: 3000.
Inside "should expect" block you don't need to send extra #stub message to objects

Verify message sends

With Mocketry you can check that particular object received particular message. Use "should receive" expression for this:
mock := Mock new.

mock someMessage.

mock should receive someMessage.
mock should not receive anotherMessage
You can verify that message was send to real objects. It is not only about mocks:
rect := 0@0 corner: 2@3.

rect stub "it should be here to enable message interception"
rect area

rect should receive width. "area = width * height"
And you can do this with globals too:
DateAndTime stub.
DateAndTime midnight.

DateAndTime should receive now. "inside midnight #now is called"
But you should be carefull with globals. Look at section about stubs.
Also with Mocketry you can verify that message was sent to set of objects. For example you can verify that message was sent to ANY object:
mock := Mock new.
rect := 0@0 corner: 2@3.
rect stub.

mock width.
rect area.

Any should receive width. "it will check that mock and rect received message #width"
Any should receive area "it will fail because mock not received #area message".
Also you can verify that ANY message was sent to particular object:
mock := Mock new.

mock someMessage should be: 100.

mock should receive anyMessage.
And both variants are supported:
mock := Mock new.
rect := 0@0 corner: 2@3.
rect stub.

mock someMessage.

Any should receive anyMessage. "will fail because rect not received any message".

rect width.

Any should receive anyMessage. "will not fail because both objects received at least one message"
Any class is specific object spec which means "any" object. You can uses any kind of specs to verify message send for set of objects:
rect := 0@0 corner: 2@3.
rect stub.

rect area.

rect2 := 0@0 corner: 4@5.
rect2 width.

(Kind of: Rectangle) should receive width. "will not fail because both rect's received message #width"
(Kind of: Rectangle) should receive area "will fail because rect2 not received message #area"

mock := Mock new.
(Kind of: Rectangle) should receive width. "will not fail because mock is not kind of Rectangle"

Verify message sends with arguments

In place of message arguments you can use expected objects itself. Or you can put specifications for expected arguments:
mock := Mock new.

(mock messageWith: 10) should be: #ten.
(mock messageWith: 'test' should be: #anyString.

mock should receive messageWith: 10.
mock should receive messageWith: (Instance of: SmallInteger).
mock should receive messageWith: 'test'.
mock should receive messageWith: (Kind of: String).
mock should receive messageWith: [:arg | arg isNumber].

Capture message arguments

Mocketry provides suitable tool to capture arguments of messages for subsequent verification:
mock := Mock new.
mock someMessageWith: Arg argName.

mock someMessageWith: #argValue.

Arg argName should be: #argValue.
As argument spec capture plays role of any object. So it not restricts message send expectation. Capture will store all received argument values. To verify concrete argument use message #fromCall:
Arg argName fromFirstCall should be: #value1.
Arg argName fromLastCall should be: #value3.
(Arg argName fromCall: 2) should be: #value2.
Short version:
Arg argName should be: #argValue.
will signal error if there are multiple different captured values.
Also "should" expression on capture will verify that owner message send was occurred required number of times.
When argument is captured it value is stubbed. It allows you to verify subsequent message sends to captured arguments:
mock stub someMessageWith: Arg rectangle.

rect := 0@0 corner: 2@3.
mock someMessageWith: rect.
rect area.

Arg rectangle should be: rect.
Arg rectangle should receive width.

Verify message sends count

Mocketry allows to verify how many times object received particular message:
mock := Mock new.

mock someMessage.
mock should receive someMessage once.

mock someMessage.
mock should receive someMessage twice.

mock someMessage.
mock should receive someMessage exactly: 3.
mock should receive someMessage atLeast: 2.
mock should receive someMessage atMost: 3.
mock should receive someMessage atLeast: 1 atMost: 5.
Same works to verify that set of objects received particular message expected number of times:
mock := Mock new.
mock2 := Mock new.

mock someMessage; someMessage.
mock2 someMessage.

Any should receive someMessage twice. "will fail because mock2 received #someMessage only once"

mock2 someMessage.
Any should receive someMessage twice. "will not fail because both mocks received #someMessage twice"

Verify group of message sends

There is way to verify group of message sends at once:
mock := Mock new.
rect := 0@0 corner: 2@3.
rect stub.

mock someMessage.
rect area.

[ rect width.
mock someMessage ] should beDone.

[ mock someMessage.
rect width ] should beDoneInOrder.
#beDone don't care about order of message sends.
#beDoneInOrder verifies that messages were set in same order as they defined inside given block

Verify all expectations

There is way how to verify that all defined expectations were occurred:
mock1 := Mock new.
mock2 := Mock new.

[mock1 someMessage. mock2 someMessage2]
   should lenient satisfy:
[ mock2 someMessage2.
mock1 someMessage willReturn: 'some'].
#lenient means that we don't care about order in which expected messages were happened.
mock1 := Mock new.
mock2 := Mock new.

[mock1 someMessage. mock2 someMessage2]
   should strict satisfy:
[ mock1 someMessage willReturn: 'some'.
mock2 someMessage2].
#strict means that we want expected messages were happened in same order in which they were defined.

Update. Project was moved to github

понедельник, 4 апреля 2016 г.

Playing with ObjectVirus

I want to show ObjectVirus, special kind of ClassGhost.

But first let's look at ClassGhost. It is ghost which can play role of object classes. ClassGhost can substitute class of objects and intercept all their messages. And as ghost it intercepts all direct messages too. So concrete implementation should decide how ghost should behave itself and how normal objects should behave when they are "infected" by ghost. Subclasses of GHClassGhost should implement two kind of behaviour: #ghostBehaviour (as any other ghost) and #instancesBehaviour (to process messages to "infected" objects).

ObjectVirus makes these decisions. It delegates all direct messages to victim class. By looking at virus you will not see any difference from class which it substitutes.
And to process messages to infected objects you should define concrete ghost behaviour:
virus := GHObjectVirus behaviour: aGhostBehaviour.
To substitute class of object you should infect it by virus:
virus infect: anObject
Then you can detect infection by:
infectedObject isInfectedByVirus.
infectedObject virus
And you can recover it:
infectedObject recoverFromVirus
or
virus heal: infectedObject
Virus related methods are defined in Object too. So you can ask any object about it.

Now let's play with virus. I want to infect morphs on screen such way that when infected morph will touch another morph it will paint it by own color. For this we need to implement special behaviour. Let's call it MorphsColoring:
GHGhostBehaviour subclass: #MorphsColoring
instanceVariableNames: ''
classVariableNames: ''
package: 'MyWork'
          MorphsColoring >>send: aMessage to: aMorph
| bounds color |
GHCurrentMetaLevelDepth increaseFor: [
color := aMorph color.
bounds := aMorph bounds.
^[GHVictimMetaMessages executeOriginalMethodOf: aMorph for: aMessage]
ensure: [
(World submorphsSatisfying: [ :each |
each ~~ aMorph and: [ each bounds intersects: bounds] ])
do: [:each | each color: color].
]
]
For any message to infected morph it executes morph original method and performs extra virus side effect. It will scan all morphs on screen to detect "touching" morphs. And it will paint them by own color.
We increase current meta level here to escape possible recursion when we interact with surrounding objects. Without it "aMorph color" will produce recursive call to behaviour to process message #color which will lead to infinite recursion. When message is sent inside meta level it will not intercepted by behaviour. And in case of virus it will be performed by original method of infected object.

Now lets infect some morph by virus and play with it:
virus := GHObjectVirus behaviour: MorphsColoring new.
morph := Morph new.
virus infect: morph.
morph openInWorld.


P.S. ObjectVirus is now renamed to ObjectMutation with all related messages